#
INCLUDE
#SET OUTPUT_CONTROL  = 1 1 1 1 # for debugging

SET ALNFILE = 'glur0.ali' # The alignment filename

SET KNOWNS = 'kcsa' # The structure filenames, the pdb is called filename.atm
SET SEQUENCE = 'GluR0' # The sequence filename

SET ATOM_FILES_DIRECTORY = '.' # Working directory
SET STARTING_MODEL = 1 # Starting and ending model indices
SET ENDING_MODEL = 25
SET DEVIATION = 4.0 # Deviation in models
SET RAND_SEED = -12312 # Random seed


# Call the routine model which in turn calls all the other routines required.
CALL ROUTINE = 'model'


STOP

# Restraints
		SUBROUTINE ROUTINE = 'special_restraints'

# Symmetry
# Define the segments (chains in this case) to be identical:
DEFINE_STRING VARIABLES = SEG1 SEG2 SEG3 SEG4
CALL ROUTINE = 'defsym', SEG1 = '1' '97', SEG2 = '98' '194', SEG3 = '195' '291', SEG4 = '292' '388'

# Make them identical by optimizing the initial randomized structure
# without any other restraints:
SET DYNAMIC_SPHERE = off
ENERGY
WRITE_MODEL FILE = 'define_symmetry-1.atm'
OPTIMIZE MAX_ITERATIONS = 300
WRITE_MODEL FILE = 'define_symmetry-2.atm'
ENERGY

# Now optimize with stereochemical restraints so that the
# result is not so distorted a structure (still distorted
# because optimization is not thorough):
SET DYNAMIC_SPHERE = on
MAKE_RESTRAINTS RESTRAINT_TYPE = 'stereo'
RANDOMIZE_XYZ DEVIATION = 3.0
SET MAX_ITERATIONS = 300, MD_RETURN = 'FINAL'
OPTIMIZE OPTIMIZATION_METHOD = 1 # Conjugate gradients
OPTIMIZE OPTIMIZATION_METHOD = 3 # Molecular dynamics
OPTIMIZE OPTIMIZATION_METHOD = 1 # Conjugate gradients
WRITE_MODEL FILE = 'define_symmetry-3.atm'
ENERGY

# Helicity
SET ADD_RESTRAINTS = on
# An alpha-helix:
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '3' '29'     #M1 region (consensus)
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '44' '56'    #P region (jalview p/out)
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '68' '94'    #M2 region (consensus)
       
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '100' '126'
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '141' '153'
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '165' '191'

MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '197' '223'
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '238' '250'
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '262' '288' 

MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '294' '320'
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '335' '347'
MAKE_RESTRAINTS RESTRAINT_TYPE = 'alpha', RESIDUE_IDS = '359' '385'


RETURN
		END_SUBROUTINE

#define the atom pairs which are to be symmetrical
	SUBROUTINE ROUTINE = 'defsym'
SET ATOM_TYPES = 'MNCH'
SET RES_TYPES = 'ALL'
SET SELECTION_STATUS = 'INITIALIZE'
SET SELECTION_SEARCH = 'SEGMENT'


  SET SYMMETRY_WEIGHT = 1.0
  PICK_ATOMS PICK_ATOMS_SET = 2, SELECTION_SEGMENT = SEG1
  PICK_ATOMS PICK_ATOMS_SET = 3, SELECTION_SEGMENT = SEG2
  DEFINE_SYMMETRY ADD_SYMMETRY = on off
  PICK_ATOMS PICK_ATOMS_SET = 2, SELECTION_SEGMENT = SEG1
  PICK_ATOMS PICK_ATOMS_SET = 3, SELECTION_SEGMENT = SEG3
  DEFINE_SYMMETRY ADD_SYMMETRY = on off
  PICK_ATOMS PICK_ATOMS_SET = 2, SELECTION_SEGMENT = SEG1
  PICK_ATOMS PICK_ATOMS_SET = 3, SELECTION_SEGMENT = SEG4
  DEFINE_SYMMETRY ADD_SYMMETRY = on off
  PICK_ATOMS PICK_ATOMS_SET = 2, SELECTION_SEGMENT = SEG2
  PICK_ATOMS PICK_ATOMS_SET = 3, SELECTION_SEGMENT = SEG3
  DEFINE_SYMMETRY ADD_SYMMETRY = on off
  PICK_ATOMS PICK_ATOMS_SET = 2, SELECTION_SEGMENT = SEG2
  PICK_ATOMS PICK_ATOMS_SET = 3, SELECTION_SEGMENT = SEG4
  DEFINE_SYMMETRY ADD_SYMMETRY = on off
  PICK_ATOMS PICK_ATOMS_SET = 2, SELECTION_SEGMENT = SEG3
  PICK_ATOMS PICK_ATOMS_SET = 3, SELECTION_SEGMENT = SEG4
  DEFINE_SYMMETRY ADD_SYMMETRY = on off

RETURN
	END_SUBROUTINE